手机版 官方微博
官方微信
扫描关注:理想财富微信公众号
理想论坛App
扫描下载理想论坛App
RSS

请老师帮助把这个指标改成通达信的

[大智慧]
设置
1741 3 我12345685 Lv.4 发表于 · 2020-6-24 13:58 举报 显示全部楼层 复制 正序浏览 |
跳转到指定楼层
{主力筹码估算}
DRAWGBK(1, COLORRGB(100,100,100),COLORRGB(50,50,50),0);
{换手100%}
svol:=INTPART(SUM(V,0)/CAPITAL);
tj0:=svol>REF(svol,1) or BARSSINCE(CLOSE)=0;
S1:=BARSLAST(tj0)+1,PRECISION,COLORWHITE;//时间1
tj2:=S1<ref(S1,1);//取点
S2:=if(tj2,ref(S1,1)+1,S1),PRECISION,COLORMAGENTA;//时间2
S3:=sum(tj2,0),COLORMAGENTA;
阶段总额(万元):=SUM(AMOUNT/10000,S2)*100,PRECISION,LINETHICK,Color008BFA;//换手100%成交额
阶段总量(手):=SUM(V,S2)*100,PRECISION,LINETHICK,COLORCYAN;//换手100%成交量
阶段成本(元):=(阶段总额(万元)/(阶段总量(手)/100)),LINETHICK,PRECISION2,COLORRED;
DRAWTEXT(BARPOS=SYSPARAM(2),h,'■阶段平均成本:'+NUMTOSTR(阶段成本(元)[SYSPARAM(1)],2)+'(元)'),align4,COLORCYAN;
//
{取点}
Zk1:=STKINDI('' ,'kdj.k',0,7);
Zd2:=STKINDI('' ,'kdj.d',0,7);
ZF1:=STKINDI('' ,'macd.diff',0,7);
ZA2:=STKINDI('' ,'macd.dea',0,7);

{------------------☆功能开关--------------------}
{建仓统计}
换手率:v/FINANCE(7),LINETHICK,PRECISION2,COLORCYAN;{换手率}
JCD:=FILTER(CROSS(Zk1,Zd2)&&Zd2<30,13);{周KD金叉位置}
取点:=barslast(JCD);
吸筹区:=if(取点>0 and 取点<61,取点,0);
ZS1:=吸筹区;
ZS2:=吸筹区+1;
ZS3:=换手率/5;{庄家筹码估算}
ZSA:=IF(ZS1>0,sum((ZS3),吸筹区+1),0);{统计庄家筹码}
{控制画线高度}
n1:=sysparam(3);
nn:=n1-sysparam(2)+1;
hh:=hhv(换手率,nn);
ll:=llv(换手率,nn);
最高:=hh[n1];
最低:=ll[n1];
中:=最低+(最高-最低)*0.5;

{-----------------【图解模板】---------------------}
{换手率}
换手冷清:STICKLINE(换手率<3,0,换手率,4,1),COLORWHITE;//冷清
换手活跃:STICKLINE(换手率>=3 and 换手率<7,0,换手率,4,1),COLORYELLOW;//活跃
换手热烈:STICKLINE(换手率>=7,0,换手率,4,1),COLORRED;//热烈
{换手MA}
PARTLINE(C,MA(换手率,13)),Color0089FF;
PARTLINE(C,MA(换手率,55)),COLOR009900;

PARTLINE(RANGE(BARPOS,SYSPARAM(2),SYSPARAM(1)+1)&&ZS1>0,中),COLORCYAN;//建仓横线
VERTLINE(JCD),LINEDOT,COLORGREEN;//建仓点竖线
DRAWTEXT(BARSCOUNT(C)=SYSPARAM(1)&&SYSPARAM(1)>ZS1,中*2,'   主力建仓天数:'+NUMTOSTR(ZS1[SYSPARAM(1)],0)+'(天) '),PXDN30,align2,COLORGREEN;
DRAWTEXT(BARSCOUNT(C)=SYSPARAM(1)&&SYSPARAM(1)>ZS1,中*2,' \n 估算主力筹码:'+NUMTOSTR(ZSA[SYSPARAM(1)],2)+'% '),PXDN30,align2,COLORMAGENTA;
DRAWICON(FILTER(CROSS(ZF1,ZA2),5),0,4),align5;
DRAWICON(FILTER(CROSS(Zk1,Zd2),5),0,8),align5;
DRAWICON(FILTER(CROSS(Zd2,Zk1),5),0,9),align5;
举报

举报

扔鸡蛋(0) 回复

我lovei
Lv.2
发表于 2020-6-28 21:19 复制 查看全部楼层
看着挺好的,但不知道怎么用呢

举报

扔鸡蛋(0) 回复

我12345685
Lv.4
发表于 2020-6-25 21:55 复制 查看全部楼层
注册111 发表于 2020-6-25 11:20
试试
{主力筹码估算}
DRAWGBK(1,RGB(100,100,100),RGB(50,50,50),0,1,0);

谢谢老师..............

举报

扔鸡蛋(0) 回复

注册111
Lv.6
发表于 2020-6-25 11:20 复制 查看全部楼层
试试
{主力筹码估算}
DRAWGBK(1,RGB(100,100,100),RGB(50,50,50),0,1,0);
{换手100%}
SVOL:=INTPART(SUM(V,0)/CAPITAL);
TJ0:=SVOL>REF(SVOL,1) OR BARSSINCE(CLOSE)=0;
S1:=BARSLAST(TJ0)+1, COLORWHITE;{//时间1}
TJ2:=S1<REF(S1,1);{//取点}
S2:=IF(TJ2,REF(S1,1)+1,S1) ,COLORMAGENTA;{//时间2}
S3:=SUM(TJ2,0),COLORMAGENTA;
阶段总额:=SUM(AMOUNT/10000,S2)*100 ,NODRAW,COLOR008BFA;{//换手100%成交额}
阶段总量:=SUM(V,S2)*100,NODRAW,COLORCYAN;{//换手100%成交量}
阶段成本:=(阶段总额/(阶段总量/100)),NODRAW,COLORRED;
DRAWTEXT_FIX(1,0,0,0,STRCAT(STRCAT('■阶段平均成本:',CON2STR(阶段成本,2)),'(元)')) ,COLORCYAN;

{取点}
ZK1:=KDJ.K;
ZD2:=KDJ.D;
ZF1:=MACD.DIF;
ZA2:=MACD.DEA;

{------------------☆功能开关--------------------}
{建仓统计}
换手率:V/FINANCE(7)*100,LINETHICK ,COLORCYAN;{换手率}
JCD:=FILTER(CROSS(ZK1,ZD2)&&ZD2<30,13);{周KD金叉位置}
取点:=BARSLAST(JCD);
吸筹区:=IF(取点>0 AND 取点<61,取点,0);
ZS1:=吸筹区;
ZS2:=吸筹区+1;
ZS3:=换手率/5;{庄家筹码估算}
ZSA:=IF(ZS1>0,SUM((ZS3),吸筹区+1),0);{统计庄家筹码}
{控制画线高度}
HH:=HHV(换手率,60);
LL:=LLV(换手率,60);
最高:=HH;
最低:=LL;
中:=最低+(最高-最低)*0.5;

{-----------------【图解模板】---------------------}
{换手率}
换手冷清:STICKLINE(换手率<3,0,换手率,4,1),COLORWHITE;{//冷清}
换手活跃:STICKLINE(换手率>=3 AND 换手率<7,0,换手率,4,1),COLORYELLOW;{//活跃}
换手热烈:STICKLINE(换手率>=7,0,换手率,4,1),COLORRED;{//热烈}
{换手MA}
IF(C,MA(换手率,13),DRAWNULL),COLOR0089FF;
IF(C,MA(换手率,55),DRAWNULL),COLOR009900;

IF(ZS1>0,中,DRAWNULL),COLORCYAN;{//建仓横线}
STICKLINE(JCD,CONST(HHV(换手率,0)),CONST(LLV(换手率,0)),0,-1),COLORGREEN;{//建仓点竖线}
DRAWTEXT_FIX(ZS1,0,0.08,0,STRCAT(STRCAT('   主力建仓天数:',CON2STR(ZS1,0)),'(天) ')),COLORGREEN;
DRAWTEXT_FIX(ZS1,0,0.16,0,STRCAT(STRCAT('估算主力筹码:',CON2STR(ZSA,2)),'% ')),COLORMAGENTA;
DRAWICON(FILTER(CROSS(ZF1,ZA2),5),0,4) ;
DRAWICON(FILTER(CROSS(ZK1,ZD2),5),0,8) ;
DRAWICON(FILTER(CROSS(ZD2,ZK1),5),0,9) ;

附件

捕获.JPG

举报

点亮(0) 扔鸡蛋(0) 回复

您需要登录后才可以回帖 登录

本版积分规则 《理想财富服务协议》《免责声明》

论坛问题
微信扫一扫,添加好友咨询
驿站问题
微信扫一扫,添加好友咨询
广告投放
微信扫一扫,添加好友咨询
回顶部 到页底
快速回复 返回顶部 返回列表